home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Wonky Flux Batch 2019 02
/
Wonky_Flux_Batch_2019-02.zip
/
Wonky Flux Batch 2019-02
/
097 - EBU.dsk
/
TOOLS
/
MEMAUX.bas
< prev
next >
Wrap
BASIC Source File
|
2019-02-17
|
1KB
|
34 lines
100 REM *test for auxillary memory banks* (open-apple 12-86)
110 TEXT : HOME :SPED = 255: VTAB 10
120 PRINT "Just a minute here....": PRINT
130 DIM B(127): REM Array to remember which banks have memory.
140 POKE 49239,0: REM turn on Hires ($c057)
150 S8 = PEEK(49176): POKE 49153,0
160 P2 = PEEK(49180): POKE 49237,0
200 FOR BANK = 127 TO 0 STEP -1
210 POKE 49267,BANK: REM $C073
220 B(BANK) = PEEK(8192): REM Save value now at $2000
240 NEXT
250 FOR BANK = 127 TO 0 STEP -1
260 POKE 49267,BANK: REM $c073
270 POKE 8192,BANK: REM puts bank# at $2000
280 NEXT
300 FOR BANK = 0 TO 127
310 POKE 49267,BANK: REM $C073
320 IF PEEK(8192) < >BANK THEN 360: REM if <>then no ram bank here
330 POKE 8192,0: IF PEEK(8192) < >0 THEN 360: REM Double-check
340 POKE 8192,255: IF PEEK(8192) < >255 THEN 360: REM triple check
350 POKE 8192,B(BANK):B(BANK) = 1:B = B +1: GOTO 370
360 B(BANK) = 0
370 NEXT
380 POKE 49267,0: REM return $C073 to bank 0
381 IF P2 <128 THEN POKE 49236,0: REM fix Page1
382 IF S8 <128 THEN POKE 49236,0: REM fix Store40
400 PRINT "This machine has ";B" banks of auxilliary memory, ";
410 PRINT "for a total of ";B *64;"k."
420 PRINT
430 PRINT "This memory appears as banks:";
440 FOR BANK = 0 TO 127: IF B(BANK) = 1 THEN PRINT SPC( 3);BANK;
450 NEXT
460 HTAB 0: VTAB 19: PRINT "Program ending....................................."
465 PRINT : PRINT "Back to APPLESOFT BASIC.............": VTAB 23: END