home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 097 - EBU.dsk / TOOLS / MEMAUX.bas < prev    next >
BASIC Source File  |  2019-02-17  |  1KB  |  34 lines
  1. 100  REM *test for auxillary memory banks* (open-apple 12-86)
  2. 110  TEXT : HOME :SPED = 255: VTAB 10
  3. 120  PRINT "Just a minute here....": PRINT 
  4. 130  DIM B(127): REM Array to remember which banks have memory.
  5. 140  POKE 49239,0: REM  turn on Hires ($c057)
  6. 150 S8 =  PEEK(49176): POKE 49153,0
  7. 160 P2 =  PEEK(49180): POKE 49237,0
  8. 200  FOR BANK = 127 TO 0  STEP  -1
  9. 210  POKE 49267,BANK: REM  $C073
  10. 220 B(BANK) =  PEEK(8192): REM  Save value now at $2000
  11. 240  NEXT 
  12. 250  FOR BANK = 127 TO 0  STEP  -1
  13. 260  POKE 49267,BANK: REM   $c073
  14. 270  POKE 8192,BANK: REM  puts bank# at $2000
  15. 280  NEXT 
  16. 300  FOR BANK = 0 TO 127
  17. 310  POKE 49267,BANK: REM  $C073
  18. 320  IF  PEEK(8192) < >BANK  THEN 360: REM  if <>then no ram bank here
  19. 330  POKE 8192,0: IF  PEEK(8192) < >0  THEN 360: REM  Double-check
  20. 340  POKE 8192,255: IF  PEEK(8192) < >255  THEN 360: REM  triple check
  21. 350  POKE 8192,B(BANK):B(BANK) = 1:B = B +1: GOTO 370
  22. 360 B(BANK) = 0
  23. 370  NEXT 
  24. 380  POKE 49267,0: REM  return $C073 to bank 0
  25. 381  IF P2 <128  THEN  POKE 49236,0: REM  fix Page1
  26. 382  IF S8 <128  THEN  POKE 49236,0: REM  fix Store40
  27. 400  PRINT "This machine has ";B" banks of auxilliary memory, ";
  28. 410  PRINT "for a total of ";B *64;"k."
  29. 420  PRINT 
  30. 430  PRINT "This memory appears as banks:";
  31. 440  FOR BANK = 0 TO 127: IF B(BANK) = 1  THEN  PRINT  SPC( 3);BANK;
  32. 450  NEXT 
  33. 460  HTAB 0: VTAB 19: PRINT "Program ending....................................."
  34. 465  PRINT : PRINT "Back to APPLESOFT BASIC.............": VTAB 23: END